programming is hard

InvisibleScroller

import mx.transitions.OnEnterFrameBeacon;

/**
 * A scroller class with no visible interface
 * Uses masked area to calculate position
 */
class com.orazal.tools.InvisibleScroller {
	// Enter Frame Beacon
	static var __initBeacon = OnEnterFrameBeacon.init();
	// Target Clips
	private var mask:MovieClip;
	private var masked:MovieClip;
	// Properties
	private var dir:String = "vertical";
	private var offset:Object;
	private var oPos:Object;
	private var newPos:Number;
	private var easing:Number = 5;
	
	// Constructor
	public function InvisibleScroller(dire:String, mask_mc:MovieClip, masked_mc:MovieClip) {
		dir = dire;
		mask = mask_mc;
		masked = masked_mc;
		// Store original masked positions
		oPos = {x:masked_mc._x, y:masked_mc._y};
		offset = {x:mask._x - masked._x , y:masked._y - mask._y};
		// Start listening to mouse
		Mouse.addListener(this);
		// EnterFrame listener
		MovieClip.addListener(this);
	}
	
	/**
	 * Allows to change easing
	 */
	public function setEasing(amount):Void{
		easing = amount;
	}
	
	/**
	 * Enter Frame
	 */
	private function onEnterFrame():Void {
		if(dir == "vertical"){
				masked._y  += (newPos - masked._y )/ easing;
		}
		if(dir == "horizontal"){
				masked._x  += (newPos - masked._x )/ easing;
		}
	}
	
	/**
	 * Mouse listener
	 */
	private function onMouseMove() {
		var point:Object = {x:_root._xmouse, y:_root._ymouse};
 		mask.globalToLocal(point); 
		if(this.dir == "vertical"){
			var percent:Number = point.y/mask._height;
			var maskedTotal = offset.y + this.masked._height + 20
			var max:Number = maskedTotal - this.mask._height ;
			if(percent >= 0 && percent<=1){
				newPos =(-max*percent ) + oPos.y ;
			}
		}
		if(this.dir == "horizontal"){
			var percent:Number = point.x/mask._width;
			var maskedTotal = offset.x + this.masked._width + 20;
			var max:Number =  maskedTotal - this.mask._width ;
			if(percent >= 0 && percent<=1){
				newPos =(-max*percent ) + oPos.x;
			}
		}
			
		
	};
	
	public function destroy():Void{
		MovieClip.removeListener(this);
		Mouse.removeListener(this);
		delete this;
	}
}